Salut, j'ai trouvé qqchose qui pourrait t'être utile :

Building a Systray Icon
By Ken Howe

I've been getting a lot of requests for an example of how to put an icon in the systray. The systay is that small box near the time on the task bar. The object I've described is the main work horse and you should import this object into your Powerbuilder library.

Basically there are a bunch of API calls which this object calls. The functions on the object provide a nice friendly interface to the API calls:

Code: pb

//--START OF OBJECT
$PBExportHeader$nca_systray.sru
$PBExportComments$Systray Utilities V2.0
forward
global type nca_systray from nonvisualobject
end type
end forward

type notifyicondata from structure
  long    cbsize
  long    hwnd
  long    uid
  long    uflags
  long    ucallbackmessage
  long    hicon
  character    sztip[ 64 ]
end type

global type nca_systray from nonvisualobject autoinstantiate
end type

type prototypes
function long Shell_NotifyIcon ( long dwMessage, ref notifyicondata lpData )
library "shell32"
function long LoadImageA ( long hInstance, string lpszName, uint uType, int
a, int b, uint l ) library "user32"
function long LoadIconA( long hInstance, long lpcstr ) library 'user32'
end prototypes

type variables
Protected:
notifyicondata istr_lpdata
window iw_win
boolean ib_SystemTrayExists

CONSTANT long NIF_MESSAGE=1
CONSTANT long NIF_ICON=2
CONSTANT long NIF_TIP=4

CONSTANT long NIM_ADD=0
CONSTANT long NIM_MODIFY=1
CONSTANT long NIM_DELETE=2

end variables

forward prototypes
public subroutine addicon (string as_iconname, string as_tiptext, window aw_win)
public subroutine delicon ()
public subroutine changeicon (string as_IconName)
public subroutine changetip (string as_TipText)
public function boolean ib_systemtrayexists ()
end prototypes

public subroutine addicon (string as_iconname, string as_tiptext, window aw_win);
IF ib_SystemTrayExists THEN RETURN

iw_Win = aw_Win
istr_lpData.szTip = as_TipText + Char ( 0 )
istr_lpData.uFlags = NIF_ICON + NIF_TIP + NIF_MESSAGE
istr_lpData.uID = 100
istr_lpData.cbSize = 88
istr_lpData.hwnd = Handle ( iw_Win )
istr_lpData.uCallbackMessage = 1024
istr_lpData.hIcon = LoadImageA( 0, as_IconName, 1, 0, 0, 80 )

shell_notifyicon ( NIM_ADD, istr_lpData )

ib_SystemTrayExists = TRUE
end subroutine
public subroutine delicon ();
IF NOT ib_SystemTrayExists THEN RETURN

istr_lpData.uID = 100
istr_lpData.cbSize = 88
istr_lpData.hwnd = Handle ( iw_Win )

shell_notifyicon ( NIM_DELETE, istr_lpData )

ib_SystemTrayExists = FALSE

end subroutine

public subroutine changeicon (string as_IconName);
IF NOT ib_SystemTrayExists THEN RETURN

istr_lpData.hIcon = LoadImageA ( 0, as_IconName, 1, 0, 0, 80 )
istr_lpData.uFlags = NIF_ICON

shell_notifyicon( NIM_MODIFY, istr_lpData )


end subroutine

public subroutine changetip (string as_TipText);
IF NOT ib_SystemTrayExists THEN RETURN

istr_lpData.szTip = as_TipText + Char ( 0 )
istr_lpData.uFlags = NIF_TIP

shell_notifyicon ( NIM_MODIFY, istr_lpData )

end subroutine

public function boolean ib_systemtrayexists ();
RETURN ib_systemtrayexists
end function

on nca_systray.create
TriggerEvent( this, "constructor" )
end on

on nca_systray.destroy
TriggerEvent( this, "destructor" )
end on

event destructor;
IF ib_SystemTrayExists THEN this.DelIcon()
end event
//--END OF OBJECT

// Then in your window you need to instantiate the object and call the addicon function. In your open event call the function like:

inca_sysTray.AddIcon( 'pbbrtray.ico', 'PBBrowse V2', this )

// Then you need to add an event to your window so you can receive notification of when the user clicked your systray icon. Add an event called systray for pbm_custom01.

// Then to make the following script work, add a static text called st_status to the window and add this code to the systay event:

constant long WM_MOUSEMOVE=512
constant long WM_LBUTTONDOWN=513
constant long WM_LBUTTONUP=514
constant long WM_LBUTTONDBLCLK=515
constant long WM_RBUTTONDOWN=516
constant long WM_RBUTTONUP=517
constant long WM_RBUTTONDBLCLK=518

Choose case Message.LongParm
  case WM_MOUSEMOVE
    st_status.text = 'Mouse Moved'

  case WM_LBUTTONDOWN
    st_status.text = 'Left Mouse Down'

  case WM_LBUTTONUP
    st_status.text = 'Left Mouse Up (clicked)'

  case WM_LBUTTONDBLCLK
    st_status.text = 'Left Mouse Double Clicked'

  case WM_RBUTTONUP
    st_status.text = 'Right Mouse Up (clicked)'

  case WM_RBUTTONDOWN
    st_status.text = 'Right Mouse Down'

  case WM_RBUTTONDBLCLK
    st_status.text = 'Right Mouse Double Clicked'

  case else
    st_Status.text = 'something else happened'

end choose

Source : http://www.inquiry.com/techtips/pb_pro/ … in0798.asp

Bonjour Beagle,

Ce message est juste un avertissement pour t'indiquer que lorsque tu migreras ton application dans une version supérieure de PB,
la stucture "notifyicondata" ne sera plus "protected", mais "private". Il faudra donc en tenir compte à ce moment là pour éviter des régressions éventuelles
dans ton application.

Bonjour,

En fait, tu trouveras la réponse à toutes tes questions avec ce lien : http://www.topwizprogramming.com/freecode_icontray.html.
C'est une application libre PB avec un nvo que tu peux incorporer dans ton application illustrant la mise en oeuvre du "system icon tray".

le nvo (n_icontray) contient la méthode (of_balloon_tip) te permettant d'afficher les infos bulles tel que tu le souhaites.

effectivement, ne jamais oublier de regarder le topwiz...

sinon il y a également une source sur codexchange : http://downloads.sybase.com/codexchange … oonTip.zip  (il faut être authentifié)