$PBExportHeader$uo_notessess.sru
forward
global type uo_notessess from oleobject
end type
end forward

global type uo_notessess from oleobject
end type
global uo_notessess uo_notessess

event constructor;this.ConnectToNewObject("Lotus.NotesSession")

end event

on uo_notessess.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_notessess.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

event externalexception;
 
action = ExceptionSubstituteReturnValue! 
returnvalue = -1 
end event

event error;
 
action = ExceptionSubstituteReturnValue! 
returnvalue = -1 
end event

$PBExportHeader$uo_mail.sru
forward
global type uo_mail from nonvisualobject
end type
end forward

global type uo_mail from nonvisualobject
end type
global uo_mail uo_mail

type variables
uo_notessess ioo_NotesSes
OLEObject ioo_NotesDb

string is_emetteur

end variables

forward prototypes
public function integer of_send (string as_sendto[], string as_copyto[], string as_blindcopyto[], string as_objet, string as_corps, string as_attach[], boolean as_returnreceipt)
public function integer of_send (string as_sendto[], string as_copyto[], string as_objet, string as_corps, string as_attach[], boolean as_returnreceipt)
public function string of_get_emetteur ()
public function integer of_init (string as_pwd)
end prototypes

public function integer of_send (string as_sendto[], string as_copyto[], string as_blindcopyto[], string as_objet, string as_corps, string as_attach[], boolean as_returnreceipt);OLEObject loo_NotesDoc              // Notes document object
OLEObject loo_NotesBody          // Notes body
OLEObject rtitem              // Rich Text Item

Long i,j,k,l,m, nb
LONG ll_RetCode
STRING ls_Server
STRING ls_NotesFile             // Name of database to connect to
string ls_copyto[]
n_cst_string ln
string texte[]
long ll_cpt
long ll_max



// Create the document so a message can be sent
loo_NotesDoc = ioo_NotesDb.CreateDocument()

loo_NotesDoc.ReplaceItemValue("Form", "Memo")

/* le sujet */
loo_NotesDoc.ReplaceItemValue("Subject", as_objet)

/* le corps du message */
loo_NotesBody  = loo_NotesDoc.CreateRichTextItem("body")
  // découper le texte en ligne
ln.of_stringtoarray(as_corps,char(13)+char(10),texte)

ll_max = upperbound(texte)
for ll_cpt = 1 to ll_max
  loo_NotesBody.AppendText(texte[ll_cpt])
  loo_NotesBody.AddNewLine(1)
next

/* les fichiers attachés */
ll_max = upperbound(as_attach)

for ll_cpt = 1 to ll_max
  loo_NotesBody.AddNewLine(1)
  PopulateError(long(loo_NotesBody.EMBEDOBJECT(1454, "", as_attach[ll_cpt])),"Création attachement")
  IF Error.Number <> 0 THEN
    SignalError(-1, "Erreur attachement")
    return -1
  End If
  
next


/* SendTo */
loo_NotesDoc.ReplaceItemValue("SendTo", as_sendto)
/* CopyTo */
if upperbound(as_copyto)>0 then loo_NotesDoc.ReplaceItemValue("CopyTo", as_copyto)
/* BlindCopyTo */
if upperbound(as_blindcopyto)>0 then loo_NotesDoc.ReplaceItemValue("BlindCopyTo", as_blindcopyto)


if as_returnreceipt then 
  loo_NotesDoc.ReplaceItemValue("ReturnReceipt","1")
  loo_NotesDoc.ReplaceItemValue("DeliveryReport","1")
end if


loo_NotesDoc.SAVEMESSAGEONSEND = TRUE
loo_NotesDoc.Save( True, False, TRUE)


/* Envoyer le message */
PopulateError(long(loo_NotesDoc.SEND (FALSE)),"Envoi du mail")
IF Error.Number <> 0 THEN
  SignalError(-1, "Erreur envoi du mail")
  return -1
End If


Destroy loo_NotesBody
Destroy loo_NotesDoc

messagebox('Envoi du mail','Message envoyé')

return 1

end function

public function integer of_send (string as_sendto[], string as_copyto[], string as_objet, string as_corps, string as_attach[], boolean as_returnreceipt);string ls_blindcopyto[]

return of_send(as_sendto, as_copyto, ls_blindcopyto, as_objet, as_corps, as_attach, as_returnreceipt)

end function

public function string of_get_emetteur ();return is_emetteur
end function
public function integer of_init (string as_pwd);string ls_notespath
string ls_NotesFile
string ls_server, ls_mailfile
int li_ret


string ls_titlefont




ioo_NotesSes = CREATE uo_notessess

if not isvalid(ioo_NotesSes) then
  messagebox('Attention',"Impossible d'initialiser l'objet Notes")
  return -1
end if



if long(ioo_NotesSes.Initialize(as_pwd))<> 0 then
  messagebox('Attention','Le mot de passe est incorrect.')
  return -1
end if


ls_mailfile = string(ioo_NotesSes.GetEnvironmentString("MailFile",TRUE))
ls_server = string(ioo_NotesSes.GetEnvironmentString("MailServer",TRUE))



is_emetteur = string(ioo_NotesSes.CommonUserName)




if isnumber(string(ioo_NotesSes.getDatabase(ls_server,ls_mailfile))) then
  messagebox("Attention","Impossible d'ouvrir la base " + ls_mailfile + ". Veuillez contacter le service informatique.")
  return -1
else
  ioo_NotesDb =   ioo_NotesSes.getDatabase(ls_server,ls_mailfile)
end if  


if not ioo_NotesDb.isopen then
  messagebox("Attention","Impossible d'ouvrir la base " + ls_mailfile + ". Veuillez contacter le service informatique.")
  return -1
end if


return 1
end function
on uo_mail.create
call super::create
TriggerEvent( this, "constructor" )
end on

on uo_mail.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

uo_mail iuo_mail
iuo_mail = CREATE uo_mail

iuo_mail.of_init(ls_mot_de_passe)

ls_emetteur = iuo_mail.of_get_emetteur()

iuo_mail.of_send(ls_destinataire,ls_destinatairecopy,ls_objet,ls_corps,ls_nomfichierattache,false)