OLEObject lole_bapi, lole_logon
Integer   li_ret

// 1. création ole SAP.BAPI.1
lole_bapi = Create OLEObject
li_ret = lole_bapi.ConnectToNewObject( 'SAP.BAPI.1' )

// 2. création ole SAP.LogonControl.1
lole_logon = Create OLEObject
li_ret = lole_logon.ConnectToNewObject( 'SAP.LogonControl.1' )

// 3. nouvelle connexion
lole_bapi.Connection = lole_logon.NewConnection()

// 4. paramètres 
lole_bapi.Connection.ApplicationServer = 'aaa.bbb.ccc.ddd' 
lole_bapi.Connection.System = 'eee'
lole_bapi.Connection.SystemNumber = '12'
lole_bapi.Connection.Client = '011'
lole_bapi.Connection.Language = 'FR'
lole_bapi.Connection.User = 'user'
lole_bapi.Connection.Password = 'mdp'

// 5. Logon
lole_bapi.Connection.Logon( 0, False )
li_ret = lole_bapi.Connection.IsConnected()

MessageBox('BAPI IsConnected=', string( li_ret ))

//Instance variable 
oleobject loo_sap_func
string is_Rfc_name= ….sap_rfc_name

//1)  PB Sap Logon script

integer li_stato,li_ret

ole_bapi.object.Connection.Client = 200
// Leggere user SAP dal DB
ole_bapi.object.Connection.User = _User_name_sap
//ole_bapi.object.Connection.Password = "init"
ole_bapi.object.Connection.Language = "IT"

//Logon
ole_bapi.object.Connection.Logon(0, false )
li_stato = ole_bapi.object.Connection.IsConnected()
//messagebox("SAP","BAPI connection : " + sle_stato.text)

if li_stato = 1 then
  sle_step.text = "STEP 1: Sap Logon ok "
  //Assign connection object to ole_sap_rfc
  ole_sap_rfc.object.connection = ole_bapi.object.connection
  li_stato = ole_sap_rfc.object.connection.IsConnected()
  if li_stato = 1 then
    sle_step.text = "STEP 2: RFC connect ok "

    SetPointer(HourGlass!)    

//Now i call pb window function that then call a custom rfc developed in 
//ABAP 4 that call a standard BAPI to insert SAP planned order

li_ret = wf_rfc_ppg() //see next pb script 
       
       
    SetPointer(Arrow!)  
    
    this.enabled = false
    sle_step.text = "STEP 3: RFC competed "  
    
    ole_sap_rfc.object.Connection.Logoff()
    ole_bapi.object.Connection.Logoff()
    sle_step.text = "STEP 4: SAP LogOff “
    
    if li_Ret=1 then
      Messagebox("SAP OnLine","Export data to SAP compelted.")
    else
      Messagebox("SAP OnLine","Export data to SAP fail.",StopSign!)
    end if
     tab_import.selecttab(3)
    
  else
   Messagebox("SAP OnLine","RFC connection failed " + string(li_stato))
  end if  
else
 Messagebox("SAP OnLine","SAP logon failed " + string(li_stato))
end if


//2)  wf_rfc_ppg()

long ll_k
string ls_tipo,ls_ret
integer li_Ret,li_return,li_imp_c  

li_return = -99

// Associa il riferimento alla function di SAP
loo_sap_func = ole_sap_rfc.object.add(is_rfc_name)
//loo_sap_func = ole_sap_rfc.object.add("Z_PPG")
IF IsValid(loo_sap_func) = FALSE OR IsNull(loo_sap_func) = TRUE THEN
   MessageBox('Rfc Error',"RFC: "+is_rfc_name+" Add(RFC)-->ExceptionCodes" )
   RETURN -1
END IF


oleobject loo_table,loo_table2
//-----------------------------------------------------
// INPUT parameters for the RFC
//  parm1   String     Flag export type
//  parm2   String     Production Date
//
//  parm3          Sap table         loo_table
//
// Return
// parm4   Sap table  loo_table2
//-----------------------------------------------------
if ib_elab_weekly = True then
  ls_tipo='DAILY_WEEKLY'  //Export di Daily + Weekly
else
  ls_tipo='SAVE_WEEKLY'   //Export di solo piano Daily => RFC Conserva WeeklySAP attuale
end if

integer li_exp
li_exp = loo_sap_func.exports.count

// INPUT parameters
loo_sap_func.exports(1).value = ls_tipo
loo_sap_func.exports(2).value = f_date_to_string(idt_max_datarif)

// Parametri di LOG su SAP
if tab_import.tabpage_piano.cbx_saplog.checked = true then
  string ls_path = ""
  SELECT "PPGT12_PARAMETRI"."PPGT12_VAL_PARAMETRO"  
    INTO :ls_path  
    FROM "PPGT12_PARAMETRI"  
   WHERE "PPGT12_PARAMETRI"."PPGT12_COD_PARAMETRO" = 'logfile_sap'   ;
   
  loo_sap_func.exports(3).value = trim(ls_path)
else
  loo_sap_func.exports(3).value = 'NOLOG'
end if


//-------------------------------------------------------
//we use tables(1) as an input table for the RFC
//-------------------------------------------------------

loo_table  = loo_sap_func.tables(1)
//loo_table2 = loo_sap_func.tables(2)

//Loop to load sap table 
for ll_k=1 to dw_mixed.rowcount()
  loo_table.Rows.Add  
  loo_table.value[ll_k,1] = dw_mixed.object.divisione[ll_k]
  loo_table.value[ll_k,2] = dw_mixed.object.materiale[ll_k]
  loo_table.value[ll_k,3] = f_date_to_string(dw_mixed.object.data_rif[ll_k])
  loo_table.value[ll_k,4] = dw_mixed.object.versione[ll_k]
  loo_table.value[ll_k,5] = string(truncate(dw_mixed.object.qta[ll_k],0))
next


// Call the RFC
loo_sap_func.call

//SAP RFC populate tables(2) to return a dataset with the results of the elaboration

integer li_table_count,li_row_count,li_col,li_k
string ls_work[]
integer li_riga
li_table_count = loo_sap_func.tables.Count

if li_table_count>1 then
  li_row_count = loo_sap_func.tables(2).RowCount
  
  for li_k=1 to li_row_count
     li_riga = tab_import.tabpage_log.dw_log.insertrow(0)
    for li_col=1 to 9
      tab_import.tabpage_log.dw_log.SetItem(li_riga,li_col,loo_sap_func.tables(2).value(li_k,li_col))
    next
  next
  
  //Filter e Rowscopy da Filter Buffer
  tab_import.tabpage_log.dw_log.setfilter("right(msg_type,1)='E'")
  tab_import.tabpage_log.dw_log.filter()
  tab_import.tabpage_log.dw_log.rowsmove( 1, 9999999, Filter!, tab_import.tabpage_log.dw_log_warning,1, Primary!)
  
end if

//Testa parametro di ritorno della RFC (S=ok,N=ko)
li_imp_c= loo_sap_func.imports.Count

if li_imp_c>0 then
  ls_Ret = loo_sap_func.imports(1).value
else
  ls_Ret='0'
end if

if ls_Ret='1' then
  li_return = 1
end if

Return li_Return