forward
global type n_inet from internetresult
end type
end forward

global type n_inet from internetresult
end type
global n_inet n_inet

type variables

private:
blob ibl_data


end variables
forward prototypes
public function integer internetdata (blob data)
public function string getstringdata ()
end prototypes

public function integer internetdata (blob data);
ibl_data = data

return 1

end function

public function string getstringdata ();
return string(ibl_data, encodingansi!)

end function

on n_inet.create
call super::create
TriggerEvent( this, "constructor" )
end on

on n_inet.destroy
TriggerEvent( this, "destructor" )
call super::destroy
end on

Blob lbl_content, lbl_request
String ls_headers, ls_url, ls_request, ls_example
String ls_bound, ls_boundid
Long ll_leng
Integer li_rc
inet l_inet
n_inet l_ir

ls_url = "http://www.monserveur.com/mon/service.html" // <=== le paramètre "action" de ton form

//quelque données de test, tu peux utiliser ici i_PBDOM_DOCUMENT_SHIP.SaveDocumentIntoString()
ls_example = '<bidon><child id="1">some thing</child><child id="2">another thing</child></bidon>'

//détermine la "borne" de données 
ls_boundid = "42cafebabe" //valeur arbitraire, ne doit juste pas être dans les data
ls_bound = fill('-', 38 - len(ls_boundid)) + ls_boundid //38 = longeur testée avec chrome

//on construit nos data pour 1 élément (1 champ de formulaire)
//on peut répéter si on en veut plusieurs, on gardera la même borne
//chaque borne est précédée de '--' et la dernière est suivie aussi de '--'

//pour un champ de formulaire on utilise "name"
ls_request = 'Content-Disposition: form-data; name="cXML-urlencoded"~r~n' // <=== ici c'est le champ caché de ton form
//pour des fichiers on aurait en plus "filename" et "type"
//ls_request = 'Content-Disposition: form-data; name="file_1"; filename="xxx.txt"~r~n' 
//ls_request += 'Content-Type: text/xml;~r~n' //déterminer un type mime ou utiliser application/octet-stream
ls_request += "~r~n" //fin des entêtes de la part
lbl_content = blob("--" + ls_bound + "~r~n" + ls_request, encodingansi!) &
      + blob(ls_example, encodingansi!) &
      + blob("~r~n--" + ls_bound + "--" + "~r~n", encodingansi!) //la dernière borne a un -- final

//on construit les entêtes de la requête POST
//dans le cas de la transmission de données pour du multipart
//ce n'est PAS application/x-www-form-urlencoded comme le dit la doc !
//la taille indiquée est la taille de tout ce qui suit les entêtes de requête
//(les parts et leur entêtes)
ls_headers = "Content-Length: " + string(len(lbl_content)) + "~r~n"
ls_headers += "Content-Type: multipart/form-data; boundary=" + ls_bound + "~r~n"
ls_headers += "~r~n" //fin des headers

l_inet = create inet
l_ir = create n_inet

//si on indique 0, le port est déterminé automatiquement : http=80, https=443
//si on indique autre chose ce sera ce port là
li_rc = l_inet.PostURL( ls_url, lbl_content, ls_headers, 8080 /*0 = port fonction de l'url*/, l_ir)
/*
 1  Success
-1  General error
-2  Invalid URL
-4  Cannot connect to the Internet
-5  Unsupported secure (HTTPS) connection attempted
-6  Internet request failed
*/

if li_rc = 1 then
  //OK
  //si on veut exploiter la réponse du serveur, c'est ici
  string ls_resp
  ls_resp = l_ir.getstringdata( )
  //messagebox("POST result", ls_resp)
  //mle_resp.text = ls_resp
else
  //Paf! - Signaler un problème
  //messagebox("POST result", "PostURL returned " + string(li_rc))
  //mle_resp.text = "PostURL returned " + string(li_rc)
end if

destroy l_ir
destroy l_inet

Je pourrais vous conseiller d'utiliser des
controles ActiveX pour répondre à vos besoins:

http://www.dart.com/web-activex-wininet-library-api.aspx
http://www.dart.com/ctl_web.aspx

N'ayant jamais développé avec ces objets, je vous invite vivement à
utiliser la communauté PowerBuilder
( http://scn.sap.com/community/developer-center/powerbuilder ) pour
savoir si d'autres solutions s'offrent à vous.

public function long uf_traitement_webservices (string as_methode_http, string as_url, string as_donnees_envoyees, string as_header[], ref long al_code_http, ref string as_donnees_retour, ref string as_type_retour);
long ll_upperbound_header, ll_index_header, ll_retour, ll_retour_fct = 0
any la_retour
string ls_type_envoi, ls_certificat, ls_certificat_ini, ls_password_certificat = ''

as_methode_http = upper(f_coalesce({as_methode_http, ''}))


if not f_in(as_methode_http, "GET,POST,PUT,DELETE") then 
  is_complement_erreur = as_methode_http
  il_erreur = 1
  return -1
end if

as_url = f_coalesce({as_url, ''})

if as_url = '' then 
  il_erreur = 2
  return -1
end  if

//connexion à la DLL
oleobject lole_ws

lole_ws = create oleobject

try 
  la_retour = lole_ws.connectToNewObject("ws_declaration_sociale.main")
catch (runtimeerror e )
  
end try

//traitement du retour de connexion si différent de 0 alors la connexion a échouée
if la_retour <> 0 then 
  il_erreur = 7
end if


if il_erreur = 0 then 
  
  
  try 
    //on vérifié dans le fichier ini s'il y a besoin d'un certificat ou un traitement particulier sur le certificat serveur en fonction de la plateforme cible et on le met en place
    if is_index_certificat_developpement <> "" and ib_test_editeur and il_plateforme_cible = 2 then 
      ls_certificat_ini  = profilestring(gs_fichier_ini, "TEST",is_index_certificat_developpement, "") 
    
      ls_certificat = f_get_dictionary_string(ls_certificat_ini, "CERT")
      ls_password_certificat = f_get_dictionary_string(ls_certificat_ini, "PASS")
    
      lole_ws.SetClientCertificate(ls_certificat, ls_password_certificat)
    
    elseif il_plateforme_cible = 1 or il_plateforme_cible = 3 then 
      ls_certificat_ini = profilestring(gs_fichier_ini, "Cert-NE","trusAllCertificatePolicy", "")
  
      if ls_certificat_ini <> "" then 
        lole_ws.setTrusAllCertificatePolicy(ls_certificat_ini  )
      end if
    end if  
  catch (runtimeerror e1 )
                //traitement des erreur pour les certificats
    il_erreur = 4
    is_complement_erreur = "Problème lors de la mise en place de certificat client ou de la stratégie lors d'erreur de certificat serveur"
  end try
    
  if il_erreur = 0 then 
                //envoi de la requête http(s)
    try 
      al_code_http = lole_ws.reqHttp(as_url, as_methode_http,  as_header, as_donnees_envoyees)
    catch (runtimeerror e2 )
                        //traitement d'erreur de l'envoir de requête
      il_erreur = 4
      is_complement_erreur = "Erreur lors de la requete HTTP(S)"
    end try 
  end if
  if il_erreur = 0  then 
  
    //traitement du retour
    try     
      as_donnees_retour = string(lole_ws.GetRequestResponse())
    catch(runtimeerror e3 )
      il_erreur = 4
      is_complement_erreur = "Erreur lors de la récupération du message retour du WebServices"
    end try
    //as_type_retour =  string(lole_srvHTTP.getResponseHeader("Content-Type") )
    
    //messagebox(stringal_code_http), as_donnees_retour)
  end if
  
end if


//déconnexion et destruction de l'objet OLE
if isvalid (lole_ws) then ll_retour = lole_ws.disconnectobject( )

if isvalid (lole_ws) then destroy lole_ws

//si il_erreur et différent de 0 alros on retourne -1 pour un traitement éventuel par l'appelant
if il_erreur <> 0 then return -1 

return 1
end function