/****************************************************************************************/
/*  Supprime un dossier et son contenu avec le choix de supprimer les fichiers ou non                             */                      
/*                                        */
/* Paramètres :                                   */
/* a_repertoire  : répertoire à supprimer                          */
/* a_suppression : détermine si on supprime les fichiers contenus dans le répertoire                                */
/****************************************************************************************/

string ls_search,ls_directory,ls_file,ls_new_directory,ls_test
integer i,li_retour
ulong lu_retour_find,lu_retour_close
long ll_retour_next
boolean lb_retour_supp,lb_retour,lb_fichier_supprime

str_win32_find_data lstr_liste_file[]


lb_fichier_supprime = true

// Liste des fichiers contenus dans le dossier actuel
i = 1
ls_search = a_repertoire+gs_separateur+'*'
lu_retour_find=FindFirstFileA(ls_search,lstr_liste_file[i]) 
if lu_retour_find > 0 then 
  do 
    if lstr_liste_file[i].cfilename <> '.' and lstr_liste_file[i].cfilename <> '..' then
      
      // Si c'est un dossier on rappelle la fonction de suppression dossier
      if lstr_liste_file[i].dwFileAttributes = 16 then 
        
        // On vide le dossier et on essaye de le supprimer
        ls_directory = a_repertoire + gs_separateur + lstr_liste_file[i].cfilename
        fyb_suppression_repertoire( ls_directory, a_suppression)
        
      else
        
        ls_file = a_repertoire+gs_separateur+lstr_liste_file[i].cfilename
        lb_fichier_supprime = false
        // Si c'est un fichier 
        if a_suppression <>0 then 
          // Suppression du fichier actuel si 1
          lb_retour_supp = FileDelete(ls_file) 
          if not lb_retour_supp then 
            // Erreur suppression fichier
            FindClose(lu_retour_find)
            return 1
          end if
          lb_fichier_supprime = true
        end if    
      end if      
    end if
    i++
    ll_retour_next = FindNextFileA(lu_retour_find,lstr_liste_file[i])
    
  loop while ll_retour_next > 0 
  
  lu_retour_close = FindClose(lu_retour_find)
  
  // Si rien dans le répertoire ou suppression fichier effectuée
  if lb_fichier_supprime then
    ls_new_directory = "c:\"
    // Changement de repertoire pour pouvoir supprimer le dossier courant
    lb_retour = SetCurrentDirectoryA(ls_new_directory)
    // Suppression du répertoire    
    lb_retour=RemoveDirectoryA(a_repertoire) 
    
    if not(lb_retour) then 
      // Erreur de suppression dossier
      FindClose(lu_retour_find)
      return 2
    end if
  else
    // Si lb_fichier_supprime = false : choix de pas supprimer les fichiers
    // On ne peut alors pas supprimer les répertoires car il reste des fichiers
    FindClose(lu_retour_find)
    return 3
  end if
end if
FindClose(lu_retour_find)
return 0