dw_1.Describe("DataWindow.Objects")

public function string of_arraytostring (readonly string as_array[], readonly string as_separator);
//=of_arraytostring(as_array[], as_separator)
Long    ll_taille, ll_indice
String  ls_concatene
Boolean  lb_separe = False

//Verification prealable
IF IsNull(as_separator) THEN RETURN ""

ll_taille = upperBound(as_array)
FOR ll_indice = 1 TO ll_taille
  IF ( Not IsNull (as_array[ll_indice]) ) &
  AND as_array[ll_indice] <> "" THEN
    IF lb_separe THEN
      ls_concatene += as_separator + as_array[ll_indice]
    ELSE
      //première chaine concaténée
      ls_concatene =  as_array[ll_indice]
      lb_separe = TRUE
    END IF
  END IF
NEXT


return ls_concatene
end function

public function long of_stringtoarray (readonly string as_text &
, readonly string as_separator, ref string as_array[]);
//of_stringToArray(mle.text, "~n", ls_lignes)
//Renvoie le nombre d'elements du tableau (nbre de sous-chaine) ou -1 si erreur
long  ll_pos=0, ll_indice=1, ll_nbChaine=0
long  ll_start = 1    //position du premier caractère d'une sous-chaine
long  ll_sepLen

ll_sepLen = Len(as_separator)

//Récupérer le nombre d'élts du tableau (une seule allocation dynamique de mémoire)
ll_pos = Pos(as_text, as_separator)
DO WHILE ll_pos > 0
  ll_nbChaine ++
  ll_pos = Pos(as_text, as_separator, ll_pos + ll_sepLen)
LOOP
//Le nombre d'élts du tableau est : nbre de séparateurs  + 1
ll_nbChaine ++

//Allocation dynamique du tableau
as_array[ll_nbChaine] = ""

ll_pos = Pos(as_text, as_separator)
DO WHILE ll_pos > 0
  as_array[ll_indice] = Mid(as_text, ll_start, ll_pos - ll_start)
  //incrémentation des indices
  ll_indice ++
  ll_start = ll_pos + ll_sepLen
  ll_pos = Pos(as_text, as_separator, ll_start)
LOOP
//Ajouter le dernier
as_array[ll_indice] = Mid(as_text, ll_start)

RETURN ll_nbChaine
end function