public function integer uof_getresult (string as_methode, string as_periode, string as_date, string as_format, ref string as_result);
// Function   : Interrogation du serveur Piwik pour obtenir les résultats d'une campagne
// Auteur   : PH. BUCAILLE
// Date    : 04/10/2013

// Lecture des informations de visite sur le serveur PIWIK à l'aide de l'API Piwik
// ex: http://www.myserveur.ch/analytics/?module=API&method=Live.getLastVisitsDetails&idSite=1&period=year&date=today&format=xml&token_auth=496a8ec36212afe74e1ef63f35f5b68d&segment=customVariablePageName1==campaign;customVariableValueName1=5

// Arguments :
// as_methode     : Méthode de l'API PIWIK à utiliser pour interroger le serveur ( ex : Live.getLastVisitsDetails)
// as_periode     : day, week, month, year, range
// as_date      : today, yesterday or range (= YYYY-MM-DD,YYYY-MM-DD)
// as_format    : format de la réponse (xml, json, csv, ....)
// as_result      : Chaîne contenant le résultat de l'interrogation du serveur Piwik retourné par référence

// Valeurs retournées :
// 1   : Succés
// -1   : Erreur général
// -2   : URL Invalide
// -4   : Connexion impossible à internet 

Integer  li_ret
String   ls_request

ls_request = is_url + "/?module=API&method=" + as_methode + "&idSite=" + String(il_idsite) + "&period=" + as_periode + "&date=" + as_date + "&format=" + as_format + "&token_auth=" + is_token_auth +  "&segment=customVariablePageName1==campaign;customVariablePageValue1==" + is_guid + "&language=en"

li_ret = uof_geturl(ls_request, as_result)
IF li_ret < 0 THEN RETURN li_ret

RETURN 1

end function

public function integer uof_geturl (string as_request, ref string as_result);
// Function   : Retourne la réponse suite à l'interrogation d'une URL
// Auteur    : PH. BUCAILLE
// Date    : 05/11/2013

// Arguments :
// as_request   : URL à interroger
// as_xml     : Résultat de l'interrogation de l'URL retourné par référence

// Valeurs retournées :
// 1   : Succés
// -1   : Erreur général
// -2   : URL Invalide
// -4   : Connexion impossible à internet 

integer li_ret

IF GetContextService("Internet", iinet_base) < 0 THEN RETURN -1
  
// Avec une url invalide, on ne récupére pas une image mais en général la page d'erreur du serveur
// => le code retour de la fonction est 1 => Succès

li_ret = iinet_base.GetURL(as_request, iuo_internet_result)
IF  li_ret < 0 THEN RETURN li_ret
//  1  Success
// -1  General error
// -2  Invalid URL
// -4  Cannot connect to the Internet
    
IF NOT IsNull(iuo_internet_result.iblb_data) THEN 
  as_result = String(iuo_internet_result.iblb_data, EncodingUTF8!)
END IF  

RETURN 1

end function