salut
c'est quoi ton ordre sql ?

Tu es sur que c'est le DateTime(blob2) qui bloque et pas un verrouillage de la table ?

Tentes un if IsDate(blob2) Then ... avant

Sinon je peux te conseiller de mettre les dates dans des champs dates ...

Bonjour, personne n'a d'idée?

en plus le IsDate ne fonctionne pas avec un blob en paramètre.
Je ne sais plus quoi faire. Si mon blob n'était pas bon, je devrais sortir en erreur, mais la on reste dans le 'DateTime'

merci

ok merci

bon j'ai fait le test de passer en string mais c'est illisible, j'ai tester la conversion string avec les différents formats :
ainsi=xÚ
EncodingUTF8=x?
EncodingUTF16LE=?n???
EncodingUTF16BE=??????

je suis désolé mais je débute en PB

et je ne comprend pas non plus pourquoi le DateTime ne spécifie pas le format du blob!

oui je sais bien que le champ Blob n'est pas fait pour ca, mais je reprend de l'existant, je dois faire avec.

Je suis conscient que le problème vient surement de l'écriture mais la fonction dateTime devrait ressortir en erreur et pas rester planter! :-(

je ne sais pas trop comment faire pour comparer le contenu binaire!
si tu as une solution je suis preneur. je n'ai plus d'idées.

j'aurais au moins aimer tester avec un IsDate ou un truc dans le style avant de lancer DateTime qui ne redonne pas la main.
merci de m'aider

PS : je sais qu'un date time dans un Blob c'est pas beau mais j'ai pas le choix, l'appli est faite comme ca. Mais avec le passage en PB11 ca ne semble plus fonctionner, en tout cas pour ce cas particulier

Hmm, ca ressemblerait à "2010-12-23 10:13:14.187000" n'est-ce pas ?
Un petit reverse engineering et :

[1 .. 4]  : fraction of second as a long
[5 .. 6] = years - 1900 as an int
[7] = month -1 as a byte
[8] = day as a byte
[9] = hour as a byte
[10] = minute as a byte
[11] = second as a byte

Mais çà devrait suffir :-) :

messagebox("Relecture du datetime : ", string( DateTime(BlobMid(ablob_val_blob ,1,12)) ) )

ok en fait j'ai compris, mais il faut lire de gauche a droite et pas de droite a gauche
et comme c'est des nombre, ca ne tient pas compte du format ansi ou utf?
mes données ont été inscrite dans une version de pb en ansi alors que le le relis en PB11 qui est passé en unicode! ca peut poser problème.


Mais bon ce qui me gêne c'est que le DateTime ne rend pas la main même si le blob n'est pas bon
faut que je trouve une solution pour tester mon champ avant de faire un datetime

merci

encore moi, apres avoir fait des tests (update sur mon champ blob), le souci vient de la fraction de seconde!!! si je met 00 00 00 00 en place du 20 00 0D 00 ca passe....

du coup ca fait ramer (pas planter) le :
messagebox("Relecture du datetime : ", string( DateTime(BlobMid(lblob ,1,12)) ) )

bga a écrit:

ouai c'est bien ca mais en fait j'ai dit une bétise, cette pas cette valeur qui déconne.

Par contre j'ai pas compris comment tu étais remonté a cette date, tu pourrais m'expliquer? ca ne depend pas du format ansi ou unicode?

merci

Démonstration :

le code suivant montre comment j'en suis arrivé à cette conclusion de structure interne du datetime:

datetime ldt_now
blob{20} lbl_tmp  // 20 devrait suffir pour stocker une datetime (je ne sais pas encore la taille que cela prendra)
long i, m
//on prépare un datetime avec des valeurs remarquables
ldt_now= datetime( 1999-02-03, 04:05:06.789012)
//on encore le datetime dans notre blob cobaie
i = blobedit( lbl_tmp, 1, ldt_now )
//on va dumper le blob sous forme binaire (byte par byte, sans signification particuliere)
m = len( lbl_tmp )
byte b
string ls_dump
for i = 1 to m
  b = byte( BlobMid( lbl_tmp, i, 1 ) )
  ls_dump += string( b ) +', '
next
messagebox( "dump now ( "+string( ldt_now, "yyyy-mm-dd hh:mm:ss.ffffff" ) + ")", ls_dump )
/*
Output:
  ---------------------------
  dump now ( 1999-02-03 04:05:06.789012)
  ---------------------------
  20, 10, 12, 0, 99, 0, 1, 3, 4, 5, 6, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
  ---------------------------
  OK   
  ---------------------------
*/
//On arrive à repérer la structure correspondante, partie par partie :
ulong fsec
uint years
byte month, day, hour, minute, second
fsec = long( blobmid( lbl_tmp, 1, 4 ) )
years = integer(blobmid( lbl_tmp, 5, 2 ) ) + 1900
month = byte( blobmid( lbl_tmp, 7, 1 ) ) + 1
day = byte( blobmid( lbl_tmp, 8, 1 ) ) 
hour = byte( blobmid( lbl_tmp, 9, 1 ) ) 
minute = byte( blobmid( lbl_tmp, 10, 1 ) ) 
second = byte( blobmid( lbl_tmp, 11, 1 ) ) 
messagebox( "les elements séparés:", string(years,'0000')+"-"+string(month,'00')+"-"+string(day,'00')+' '+&
  string(hour,'00')+':'+string(minute,'00')+':'+string(second,'00')+'.'+string(fsec,'000000') )
/*
Output:
---------------------------
les elements séparés:
---------------------------
1999-02-03 04:05:06.789012
---------------------------
OK   
---------------------------
*/
//on peut maitenant facilement récupérer le datetime connaissant sa taille ( 12 bytes ).
messagebox("Le datetime provenant du blob", string( DateTime(BlobMid(lbl_tmp ,1,12)),"yyyy-mm-dd hh:mm:ss.ffffff" ) )
/*
Output:
---------------------------
Le datetime provenant du blob
---------------------------
1999-02-03 04:05:06.789012
---------------------------
OK   
---------------------------
*/

Pour finir, voici l'astuce que tu pourras utiliser pour neutraliser les fractions de secondes :

//on nettoie les factions de secondes :
long fsec_clear = 0
BlobEdit( lbl_tmp, 1, fsec_clear)
messagebox("Le datetime provenant du blob", string( DateTime(BlobMid(lbl_tmp ,1,12)),"yyyy-mm-dd hh:mm:ss.ffffff" ) )

Cela fonctionne bien sur la date qui "plantait" chez moi aussi.

xlat a écrit:

Je viens de faire un test avec la date qui plante chez toi et je reproduis la lenteur, sans l'histoire du 04 final en fait; il n'est pas pris en compte si tu fais le BlobMid(..., 12). pour le 04 final, j'obtiens 05 avec mon test, cela pourrait ressembler à un checksum ou numéro de version par exemple.
Je prend le code que j'ai mis au dessus et j'utilise la date que tu as remonté avant :

Code: pb

ldt_now= datetime( 2010-12-11, 15:10:35.852000 )

, et là, PB prend 100% du processeur et ne rend pas la main (je suis en 10.5.0.4523 pour ce test).

J'ai fais le même test en 11.5.1.4843 : ça ne plante pas et ne rame pas non plus.

Dernière modification par xlat (05-01-2011 15:10:24)